Create a Simple ABAP CDS View in ADT

1. In the context menu of your package choose New and then choose Other ABAP Repository Object.

1. Select Data Definition, then choose Next.

1. Enter the following values, then choose Next:

• Name = Z_INVOICE_ITEMS_XXX
• Description = Invoice Items
• Referenced Object: sepm_sddl_so_invoice_item
  

1. Accept the default transport request (local) by simply choosing Next again.

2. Select the entry Define View, then choose Finish

The new view appears in an editor, with the fields from the referenced object, sepm_sddl_so_invoice_item. In this editor, enter the following values:

1. Enter Z_ITEMS_XXX as the SQL view name.

   Your CDS view should now look like this:

   

   The SQL view name is the internal/technical name of the view which will be created in the database. Z_Invoice_Items is the name of the CDS view which provides enhanced view-building capabilities in ABAP. You should always use the CDS view name in your ABAP applications.

2. Delete all the fields except:

ABAP key sales_order_invoice_item_key, currency_code, gross_amount

You will now model the relationships between data sources by using some existing CDS associations. You can use associations in path expressions to access elements (fields and associations) in related data sources without specifying JOIN conditions. You can now display the element info by positioning the cursor on the data source name sepm_sddl_so_invoice_item and choosing F2.

To see the related data sources that can be accessed using associations, scroll down.
To see details about the target data source of the association header, choose the hyperlink sepm_sddl_so_invoice_header.

You will now add fields of related data sources to the SELECT list of Z_Invoice_Items, using the associations in path expressions. Each element in the path expression must be separated by a period.

1. Add the association header to your selection list, preferably with a comment, by adding the following the code. do not forget to add a comma after the previous item, gross_amount:

   ABAP

   Copy

   //      * Associations *//
           header    
   
   

   

2. You will get an error, “Field header must be included in the selection list together with field SEPM_SDDL_SO_INVOICE_ITEM.SALES_ORDER_INVOICE_KEY”. Resolve this by adding the field sepm_sddl_so_invoice_item.sales_order_invoice_key to the Select statement.

3. Add the company_name of the business partner to the SELECT list using the associations header and buyer in a path expression

4. Add the payment_status from the invoice header to the SELECT list using the association header

   ABAP

   Copy

   header.payment_status
   

   

If the invoice has been paid, you want to set the payment_status to X (true). Do this by implementing a CASE expression, assigning the alias payment_status to the CASE expression.

Remove the existing declaration, header.payment_status, and replace it with the following code. Do not forget to separate the new, calculated field paid and the association header with a comma.

case header.payment_status
    when 'P' then 'X'
    else ' '
end as paid,

You can check your code below.

You will now filter the results so that only invoice items with currency_code = 'EUR' are retrieved.

1. Add a WHERE clause:

   ABAP

   Copy

   
   WHERE currency_code = 'EUR'
   
   

   

2. Save and activate the data definition by choosing Save (Ctrl+S) and Activate (Ctrl+F3).

   

Your CDS view code should look something like this:

@AbapCatalog.sqlViewName: 'Z_ITEMS_XXX'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Invoice Items'

define view Z_INVOICE_ITEMS_XXX
  as select from sepm_sddl_so_invoice_item
{

  key sales_order_invoice_item_key,
      sepm_sddl_so_invoice_item.sales_order_invoice_key,

      header.buyer.company_name,

      currency_code,
      gross_amount,

      case header.payment_status
          when 'P' then 'X'
          else ' '
      end as paid,

      //      * Associations *//
      header
}

where
  currency_code = 'EUR'

Open the CDS View in the Data Preview by choosing F8. Your CDS View should look roughly like this: