Beginner
// Explore More Tutorials
Create ABAPDoc Comments in Your Class
2019-10-30
5 min.
Learn how to maintain ABAPDoc documentation for your class
You will learn
- How to make your program more readable by learning how to maintain
ABAPDoccomments. - How to synchronize the documentation and to display it, both in the ABAP Development Tools (ADT) and in SAP GUI.
Step 1: Open your ABAP class
First, open your ABAP class.
Step 2: Add an ABAPDoc comment
To improve readability, add an ABAPDoc comment to the class immediately before the method definition, for example:"! Method reads invoice items from database .
NOTE: You must insert the ABAPDoc comment immediately before the declaration; otherwise you will get a warning from ADT.
ABAPDoc comments can be used to document APIs and are displayed in the Element Info. All ABAPDoc comments begin with "! .
Step 3: Add parameters to ABAPDoc
You can also use ABAPDoc to document method parameters with a Quick Assist. Place the cursor inside of the ABAPDoc comment. Then choose **Ctrl+1** to open the Quick Assist menu and double-click on Add missing parameters to documentation:
The ABAPDoc comment is extended by a @parameter ... |. You can now use this to document the method parameters: To do so, just enter the documentation after the pipe symbol (|).
Step 4: Synchronize short texts
We have documented our method using ABAPDoc. However, we also want to see the same short texts in the description fields of the form-based Class Builder in SAP GUI.
To do this, we need to tag the required text in the ABAPDoc as “synchronized” to ensure that it is synchronized with the Class Builder.
-
Mark the short text for your method in ABAPDoc as “synchronized” by surrounding it with the tag
<p class="shorttext synchronized">...</p>. -
Do the same for the short text of your parameter
lt_result:
Step 5: Save and activate
Step 6: Link with Editor
Finally you will check that the synchronized short texts are also shown in the Class Builder. First we have to open the class in SAP GUI.
To easily find the class in SAP GUI, first choose Link with Editor:
Step 7: View the ABAPDoc comments in SAP GUI
-
In the Project Explorer, select the class
ZCL_INVOICE_RETRIEVALand choose Open with SAP GUI from the context menu:
-
The method description shows the text we entered in the ABAPDoc comment in the synchronized tag:
-
Now choose Parameters. You will see that the description of the parameter has also been synchronized:
-
Finally, close the class in SAP GUI and return to your ABAP program by choosing Close:
Step 8: Display element info
-
Back in the ABAP Program, position the cursor on the method call
GET_ITEMS_FROM_DBand display the Element Info of the method by choosing Element Info (F2). In addition to the method signature it also shows the ABAPDoc you wrote before:
-
Close the Element Info by choosing ESC.
The code for your class should now look like this:
CLASS zcl_invoice_retrieval DEFINITION
PUBLIC
FINAL
CREATE PUBLIC .
PUBLIC SECTION.
TYPES: ty_table_of_zso_invoice_item TYPE STANDARD TABLE OF zso_invoice_item WITH DEFAULT KEY.
"! <p class="shorttext synchronized">Read items from DB</p>
"! Method reads invoice items from the database
"! @parameter lt_result | <p class="shorttext synchronized">Table of invoice items</p>
"!
METHODS get_items_from_db
RETURNING
VALUE(lt_result) type ty_table_of_zso_invoice_item.
PROTECTED SECTION.
PRIVATE SECTION.
ENDCLASS.
CLASS zcl_invoice_retrieval IMPLEMENTATION.
METHOD get_items_from_db.
SELECT
snwd_bpa~company_name,
snwd_so_inv_item~gross_amount,
snwd_so_inv_item~currency_code,
snwd_so_inv_head~payment_status
FROM
snwd_so_inv_item
JOIN snwd_so_inv_head ON snwd_so_inv_item~parent_key = snwd_so_inv_head~node_key
JOIN snwd_bpa ON snwd_so_inv_head~buyer_guid = snwd_bpa~node_key
INTO TABLE @lt_result
WHERE
snwd_so_inv_item~currency_code = 'USD'
ORDER BY
snwd_bpa~company_name.
LOOP AT lt_result ASSIGNING FIELD-SYMBOL(<entry>).
CASE <entry>-payment_status.
WHEN 'P'.
<entry>-payment_status = abap_true.
WHEN OTHERS.
<entry>-payment_status = abap_false.
ENDCASE.
ENDLOOP.
ENDMETHOD.
ENDCLASS.
Step 9: Test yourself
Navigate tutorial steps