Skip to Content

Get Data from a Remote System Using a Custom Entity

test

0 %

Get Data from a Remote System Using a Custom Entity

Details

// Explore More Tutorials

Get Data from a Remote System Using a Custom Entity

Requires Customer/Partner License

Julie Plummer

09/30/2019

Advanced

45 min.

SAP Cloud Platform, ABAP environment, SAP Cloud Platform, Tutorial, Advanced, ABAP Development, Cloud

Get data from an on-Premise System Using RFC, by Implementing a Custom Entity in ABAP Environment

You will learn

How to create a suitable custom entity to get data from a remote system
How to implement a query provider class to get the data, using a BAPI (Business Application Programming Interface)
How to expose the custom entity as a business service
How to display the data in a Fiori Elements Preview, using the service binding

A BAPI is a standard interface to a business object model, implemented as a function module. For more information, see: BAPI

Custom entities are used for data models whose runtime is implemented manually. There is no SELECT statement on the data source. Rather, you define the elements and their types in the custom entity. Then you implement the data retrieval logic in an ABAP class, which is referenced in an entity annotation.
Custom entities allow you to get data using an OData service or, as here, using RFC.

For more information on CDS custom entities, see SAP Help Portal: Using a CDS Custom Entity to Define the Data Model for an OData Service

To see this tutorial group as a blog series by Andre Fischer, see: How to call a remote function module in your on-premise SAP system from SAP Cloud Platform – ABAP Environment

This includes a longer class code sample, which implements filtering.

Step 1: Create a class

First, you create the class that implements the data retrieval logic.

In ADT, open your ABAP package and choose New > Class.
Enter a name and description:
- zcl_product_via_rfc_xxx
- Read product data via RFC
Choose the transport request, then choose Finish.

Log on to answer question

Step 2: Add the interfaces statement

The signature of the method IF_A4C_RAP_QUERY_PROVIDER~SELECT contains the import parameter io_request. This parameter represents the OData query options that are delegated from the UI and used as input for the SELECT method. Whenever the OData client requests data, the query implementation class must return the data that matches the request, or throw an exception if the request cannot be fulfilled.

Implement the interface by adding this statement to the public section:

interfaces if_rap_query_provider.
Choose Quick Fix (Ctrl+1), then choose Add implementation for SELECT….

Later in this tutorial, you will implement the SELECT method of the interface.

Log on to answer question

Step 3: Create a custom entity (CDS View)

Now choose New > Other… > Core Data Services > Data Definition.
Enter a name and description:
- zce_product_via_rfc_xxx
- Read product data via RFC from On-Premise
Choose the transport request, then choose Next. Do not choose Finish, yet!
Choose Define Custom Entity with Parameters, then choose Finish. Ignore the errors for now.

Log on to answer question

Step 4: Specify the class in the custom entity

View Full Instructions

Add the following annotation to the view, pointing to the class you have just created:


@ObjectModel.query.implementedBy: 'ABAP:zcl_product_via_rfc_xxx'

Log on to answer question

Step 5: Define the CDS view

View Full Instructions

Remove the following lines from the view:



define root custom entity zce_product_via_rfc_xxx
with parameters parameter_name : parameter_type {
 key key_element_name : key_element_type;
 element_name : element_type;

}

Add the following to the view, after the @QueryImplementedBy annotation:


@UI: {
  headerInfo: {
  typeName: 'Product',
  typeNamePlural: 'Products'
  }
}

define root custom entity zce_product_via_rfc_xxx
{

      @UI.facet     : [
        {
          id        :       'Product',
          purpose   :  #STANDARD,
          type      :     #IDENTIFICATION_REFERENCE,
          label     :    'Product',
          position  : 10 }
      ]
      // DDL source code for custom entity for BAPI_EPM_PRODUCT_HEADER

      @UI           : {
      lineItem      : [{position: 10, importance: #HIGH}],
      identification: [{position: 10}],
      selectionField: [{position: 10}]
      }
  key ProductId     : abap.char( 10 );
      TypeCode      : abap.char( 2 );
      @UI           : {
      lineItem      : [{position: 20, importance: #HIGH}],
      identification: [{position: 20}],
      selectionField: [{position: 20}]
      }
      Category      : abap.char( 40 );
      @UI           : {
      lineItem      : [{position: 30, importance: #HIGH}],
      identification: [{position: 30}]
      }
      Name          : abap.char( 255 );
      @UI           : {
      identification: [{position: 40}]
      }
      Description   : abap.char( 255 );
      SupplierId    : abap.char( 10 );
      SupplierName  : abap.char( 80 );
      TaxTarifCode  : abap.int1;
      @Semantics.unitOfMeasure: true
      MeasureUnit   : abap.unit( 3 );
      @Semantics.quantity.unitOfMeasure: 'WeightUnit'
      WeightMeasure : abap.quan( 13, 3 );
      @Semantics.unitOfMeasure: true
      WeightUnit    : abap.unit( 3 );
      @UI           : {
      lineItem      : [{position: 50, importance: #HIGH}],
      identification: [{position: 50}]
      }
      Price         : abap.dec( 23, 4 );
      @Semantics.currencyCode: true
      CurrencyCode  : abap.cuky( 5 );
      @Semantics.quantity.unitOfMeasure: 'DimUnit'
      Width         : abap.quan( 13, 3 );
      @Semantics.quantity.unitOfMeasure: 'DimUnit'
      Depth         : abap.quan( 13, 3 );
      @Semantics.quantity.unitOfMeasure: 'DimUnit'
      Height        : abap.quan( 13, 3 );
      @Semantics.unitOfMeasure: true
      DimUnit       : abap.unit( 3 );
      ProductPicUrl : abap.char( 255 );

}

You will now implement the data retrieval logic in the class.

Log on to answer question

Step 6: Define some variables in the class

View Full Instructions

Go back to the class. You will start by defining an local internal table and structure, which you will fill by retrieving the data from the back end. The type of the local variables is the CDS View that you just created. Add the following code to the if_rap_query_provider~select method.


DATA lt_product TYPE STANDARD TABLE OF zce_product_via_rfc_xxx.
DATA ls_product TYPE zce_product_via_rfc_xxx.

Log on to answer question

Step 7: Define the connection to the on-premise system

Define the connection as follows, replacing XXX in both i_name and i_service_instance_name to your initials or group number. Ignore the warning for now.

```ABAP

DATA(lo_rfc_dest) = cl_rfc_destination_provider=>create_by_cloud_destination(
                            i_name                  = 'ES5_RFC_XXX'
                            i_service_instance_name = 'OutboundComm_for_RFCDemo_XXX'
   ).

DATA(lv_rfc_dest_name) = lo_rfc_dest->get_destination_name( ).

```

Log on to answer question

Step 8: Call the remote BAPI

View Full Instructions

Check whether data is being requested.


IF io_request->is_data_requested( ).

ENDIF.

If so, call the BAPI.


DATA lv_maxrows TYPE int4.

 DATA(lv_skip) = io_request->get_paging( )->get_offset(  ).
 DATA(lv_top) = io_request->get_paging( )->get_page_size(  ).

 lv_maxrows = lv_skip + lv_top.

 CALL FUNCTION 'BAPI_EPM_PRODUCT_GET_LIST'
   DESTINATION lv_rfc_dest_name
   EXPORTING
     max_rows   = lv_maxrows
   TABLES
     headerdata = lt_product.

Log on to answer question

Step 9: Set the total number of records and return the data

View Full Instructions

Set the total number of records requested.


IF io_request->is_total_numb_of_rec_requested( ).
io_response->set_total_number_of_records( lines( lt_product ) ).
ENDIF.

Return the data in the internal table.
```
io_response->set_data( lt_product ).
```

Log on to answer question

Step 10: Catch the exception if raised

Wrap the whole BAPI call in a TRY...CATCH block. Add the TRY. statement immediately after the DATA declarations. Add the CATCH. ... ENDTRY. statements just before ENDMETHOD..

```ABAP

TRY.
...
  CATCH cx_rfc_dest_provider_error INTO DATA(lx_dest).
ENDTRY.

```

![Image depicting step10-try-catch](step10-try-catch.png)

Log on to answer question

Step 11: Check the code for your class

View Full Instructions


CLASS zcl_product_via_rfc_xxx DEFINITION
  PUBLIC
  FINAL
  CREATE PUBLIC .

  PUBLIC SECTION.
    INTERFACES if_rap_query_provider.
  PROTECTED SECTION.
  PRIVATE SECTION.
ENDCLASS.

CLASS zcl_product_via_rfc_xxx IMPLEMENTATION.
  METHOD if_rap_query_provider~select.

    "variables needed to call BAPIs - zce_product_via_rfc_xxx = the CDS View
    DATA lt_product TYPE STANDARD TABLE OF zce_product_via_rfc_xxx.
    DATA ls_product TYPE zce_product_via_rfc_xxx.

      TRY.
          DATA(lo_rfc_dest) = cl_rfc_destination_provider=>create_by_cloud_destination(
                                i_name                  = 'ES5_RFC_XXX'
                                i_service_instance_name = 'OutboundComm_for_RFCDemo_XXX'

                                     ).

          DATA(lv_rfc_dest_name) = lo_rfc_dest->get_destination_name( ).


          IF io_request->is_data_requested( ).

                DATA lv_maxrows TYPE int4.

                DATA(lv_skip) = io_request->get_paging( )->get_offset(  ).
                DATA(lv_top) = io_request->get_paging( )->get_page_size(  ).

                lv_maxrows = lv_skip + lv_top.

*               Retrieve data by calling BAPI
                CALL FUNCTION 'BAPI_EPM_PRODUCT_GET_LIST'
                  DESTINATION lv_rfc_dest_name
                  EXPORTING
                    max_rows   = lv_maxrows
                  TABLES
                    headerdata = lt_product.

*            Set total no. of records
             IF io_request->is_total_numb_of_rec_requested( ).
                io_response->set_total_number_of_records( lines( lt_product ) ).
             ENDIF.

*            Output the data
             io_response->set_data( lt_product ).

          ENDIF.
      CATCH cx_a4c_rap_query_provider INTO DATA(lx_exc).
    ENDTRY.

  ENDMETHOD.
ENDCLASS.

Log on to answer question

Step 12: Create a service definition

Now that you have defined your view, and retrieved the data using the class, you can expose the view as a service. A service consists of a definition and a binding. This allows you to provide several bindings for the same definition, e.g. to expose the service to a UI, and to an A2X provider. Start with the definition:

From your package, select your custom entity, zce_product_via_rfc_xxx, then choose New > Service Definition from the context menu, then choose Next.
Choose a name and description:
- ZSD_A4C_RFC_XXX
- Read product data via RFC
Choose the transport request; choose Next.
Use the selected template; choose Finish. The name of your custom entity is inserted automatically.
Save and activate ( Ctrl+S, Ctrl+F3 ) the service definition.

Log on to answer question

Step 13: Create the service binding

Select your service definition, then choose Service Binding from the context menu, then choose Next.
Choose:
- Name = ZSB_A4C_RFC_XXX
- Description = Read product data via RFC
- Binding Type = ODATA V2 (UI…)
- Service Definition = ZSD_A4C_RFC_XXX
Choose the transport request; choose Next.
Use the selected template; choose Finish.

The service binding automatically references the service definition and thus the exposed custom entity.

Log on to answer question

Step 14: Activate the service binding;

In the editor that appears, choose Activate.
You can now see the Service URL and Entity Set.

Log on to answer question

Step 15: Display the Fiori Elements Preview

Select the entity set and choose Preview.
Log in using your ABAP Environment user and password; the Fiori Elements Preview appears.
Display the data by choosing Go.

Log on to answer question

Step 16: Test yourself

In which entity do you specify that your service is to be consumed by a SAPUI5 application? Choose one answer only: Service Definition Service Consumption Model Service Binding

×

Step 17: Troubleshooting: Test data retrieval using the ABAP Console

View Full Instructions

If the data does not display, check that the BAPI is retrieving the data, as follows:

Open the class you created in Test the Connection to the Remote System.

Replace the type ty_bapi_epm_product_header:


DATA lt_product TYPE STANDARD TABLE OF  ty_bapi_epm_product_header.
DATA ls_product TYPE ty_bapi_epm_product_header.

with the type of your custom entity:

```ABAP

DATA lt_product TYPE STANDARD TABLE OF zce_product_via_rfc_xxx.
DATA ls_product TYPE zce_product_via_rfc_xxx.

```

The console output should look like this:

Image depicting test-output-in-console

Log on to answer question

Next Steps

Navigate tutorial steps

Step 1: Create a class
Step 2: Add the interfaces statement
Step 3: Create a custom entity (CDS View)
Step 4: Specify the class in the custom entity
Step 5: Define the CDS view
Step 6: Define some variables in the class
Step 7: Define the connection to the on-premise system
Step 8: Call the remote BAPI
Step 9: Set the total number of records and return the data
Step 10: Catch the exception if raised
Step 11: Check the code for your class
Step 12: Create a service definition
Step 13: Create the service binding
Step 14: Activate the service binding;
Step 15: Display the Fiori Elements Preview
Step 16: Test yourself
Step 17: Troubleshooting: Test data retrieval using the ABAP Console
Back to Top

QR code

Back to top