Get Data from a Remote System Using a Custom Entity

Add the following annotation to the view (immediately after the ‘@EndUserText.label’ annotation), pointing to the class you have just created - NOTE: Use upper case!

@ObjectModel.query.implementedBy: 'ABAP:ZCL_PRODUCT_VIA_RFC_XXX'

1. Remove the following lines from the view:

   
   
   define root custom entity zce_product_xxx
   with parameters parameter_name : parameter_type {
    key key_element_name : key_element_type;
    element_name : element_type;
   
   }
   
   

2. Add the header information to the view, after the @QueryImplementedBy annotation.
   For more information on the UI Annotations used here, see
   SAP Help Portal: SAP BTP: ABAP RESTful PM: Defining UI Annotations

   
   @UI: {
     headerInfo: {
     typeName: 'Product',
     typeNamePlural: 'Products'
     }
   }
   
   

3. Add the fields and their associations.

   
   define root custom entity zce_product_xxx
   {
   
         @UI.facet     : [
           {
             id        :       'Product',
             purpose   :  #STANDARD,
             type      :     #IDENTIFICATION_REFERENCE,
             label     :    'Product',
             position  : 10 }
         ]
         // DDL source code for custom entity for BAPI_EPM_PRODUCT_HEADER
   
         @UI           : {
         lineItem      : [{position: 10, importance: #HIGH}],
         identification: [{position: 10}],
         selectionField: [{position: 10}]
         }
     key ProductId     : abap.char( 10 );
         TypeCode      : abap.char( 2 );
         @UI           : {
         lineItem      : [{position: 20, importance: #HIGH}],
         identification: [{position: 20}],
         selectionField: [{position: 20}]
         }
         Category      : abap.char( 40 );
         @UI           : {
         lineItem      : [{position: 30, importance: #HIGH}],
         identification: [{position: 30}]
         }
         Name          : abap.char( 255 );
         @UI           : {
         identification: [{position: 40}]
         }
         Description   : abap.char( 255 );
         SupplierId    : abap.char( 10 );
         SupplierName  : abap.char( 80 );
         TaxTarifCode  : abap.int1;
         @Semantics.unitOfMeasure: true
         MeasureUnit   : abap.unit( 3 );
         @Semantics.quantity.unitOfMeasure: 'WeightUnit'
         WeightMeasure : abap.quan( 13, 3 );
         @Semantics.unitOfMeasure: true
         WeightUnit    : abap.unit( 3 );
         @UI           : {
         lineItem      : [{position: 50, importance: #HIGH}],
         identification: [{position: 50}]
         }
         Price         : abap.dec( 23, 4 );
         @Semantics.currencyCode: true
         CurrencyCode  : abap.cuky( 5 );
         @Semantics.quantity.unitOfMeasure: 'DimUnit'
         Width         : abap.quan( 13, 3 );
         @Semantics.quantity.unitOfMeasure: 'DimUnit'
         Depth         : abap.quan( 13, 3 );
         @Semantics.quantity.unitOfMeasure: 'DimUnit'
         Height        : abap.quan( 13, 3 );
         @Semantics.unitOfMeasure: true
         DimUnit       : abap.unit( 3 );
         ProductPicUrl : abap.char( 255 );
   
   }
   
   

You will now implement the data retrieval logic in the class.

Go back to the class.

1. You will start by defining an local internal table, which you will fill by retrieving the data from the back end. The type of the local variable is the CDS View that you just created. Add the following code to the if_rap_query_provider~select method.

   
   DATA lt_product TYPE STANDARD TABLE OF zce_product_xxx.
   
   

2. Create a variable, lv_abap_trial. If you are using the full version of SAP BTP, ABAP Environment, set it to false, otherwise true.

   
   DATA(lv_abap_trial) = abap_false.  
   
   

1. Check whether data is being requested.

   
   IF io_request->is_data_requested( ).
   
   ENDIF.
   

2. Now add an IF... ELSE. ... ENDIF. block.

3. If you are using the trial version, fill the internal table lt_product with the mock data. If not, call the BAPI.

   
    DATA lv_maxrows TYPE int4.
   
    DATA(lv_skip) = io_request->get_paging( )->get_offset(  ).
    DATA(lv_top) = io_request->get_paging( )->get_page_size(  ).
   
    lv_maxrows = lv_skip + lv_top.
   
    IF lv_abap_trial = abap_true.
         lt_product = VALUE #( ( productid = 'HT-1000' name = 'Notebook' )
                               ( productid = 'HT-1001' name = 'Notebook' )
                               ( productid = 'HT-1002' name = 'Notebook' )
                               ( productid = 'HT-1003' name = 'Notebook' )
                               ( productid = 'HT-1004' name = 'Notebook' )
                               ( productid = 'HT-1005' name = 'Notebook' )
                         ).
   
   
   ELSE.                      
    CALL FUNCTION 'BAPI_EPM_PRODUCT_GET_LIST'
      DESTINATION lv_rfc_dest_name
      EXPORTING
        max_rows   = lv_maxrows
      TABLES
        headerdata = lt_product.
   
   ENDIF.
   
   

1. Set the total number of records requested.

   
   IF io_request->is_total_numb_of_rec_requested( ).
   io_response->set_total_number_of_records( lines( lt_product ) ).
   ENDIF.
   
   

2. Output the data in the internal table.

   
   io_response->set_data( lt_product ).
   
   

CLASS `zcl_product_via_rfc_xxx` DEFINITION
  PUBLIC
  FINAL
  CREATE PUBLIC .

  PUBLIC SECTION.
    INTERFACES if_rap_query_provider.
  PROTECTED SECTION.
  PRIVATE SECTION.
ENDCLASS.

CLASS `zcl_product_via_rfc_xxx` IMPLEMENTATION.
  METHOD if_rap_query_provider~select.

    DATA lt_product TYPE STANDARD TABLE OF  ZCE_PRODUCT_XXX .

    "In the trial version we cannot call RFC function module in backend systems
    DATA(lv_abap_trial) = abap_true.

    "Set RFC destination
    TRY.

      data(lo_rfc_dest) = cl_rfc_destination_provider=>create_by_cloud_destination(
            i_name = 'ES5_RFC_XXX'
            ).

      DATA(lv_rfc_dest_name) = lo_rfc_dest->get_destination_name(  ).


        "Check if data is requested
        IF io_request->is_data_requested(  ).

            DATA lv_maxrows TYPE int4.
            DATA(lv_skip) = io_request->get_paging( )->get_offset(  ).
            DATA(lv_top) = io_request->get_paging( )->get_page_size(  ).
            lv_maxrows = lv_skip + lv_top.

                IF lv_abap_trial = abap_true.
                    lt_product = VALUE #(
                              ( productid = 'HT-1000' name = 'Notebook' )
                              ( productid = 'HT-1001' name = 'Notebook' )
                              ( productid = 'HT-1002' name = 'Notebook' )
                              ( productid = 'HT-1003' name = 'Notebook' )
                              ( productid = 'HT-1004' name = 'Notebook' )
                              ( productid = 'HT-1005' name = 'Notebook' )
                              ).

                ELSE.
                  "Call BAPI
                  CALL FUNCTION 'BAPI_EPM_PRODUCT_GET_LIST'
                       DESTINATION lv_rfc_dest_name
                       EXPORTING
                         max_rows   = lv_maxrows
                       TABLES
                         headerdata = lt_product
                         .

                ENDIF.
                  "Set total no. of records
                  io_response->set_total_number_of_records( lines( lt_product ) ).
                  "Output data
                  io_response->set_data( lt_product ).

        ENDIF.

    CATCH  cx_rfc_dest_provider_error INTO DATA(lx_dest).
    ENDTRY.


  ENDMETHOD.
ENDCLASS.

If the data does not display (and you are using the licensed version), check that the BAPI is retrieving the data, as follows:

1. Open the class you created in Test the Connection to the Remote System.

2. Replace the type ty_bapi_epm_product_header:

   
   DATA lt_product TYPE STANDARD TABLE OF  ty_bapi_epm_product_header.
   DATA ls_product TYPE ty_bapi_epm_product_header.
   
   

with the type of your custom entity:

```ABAP

DATA lt_product TYPE STANDARD TABLE OF zce_product_via_rfc_xxx.
DATA ls_product TYPE zce_product_via_rfc_xxx.

```

The console output should look like this: