Implement the Logical Deletion

Open your CDS view ZCAL_HOLIDAY_XXX and add following UI annotation:

@UI.hidden: true

Add the where condition at the end of your CDS View ZCAL_HOLIDAY_XXX:

where configdeprecationcode = ''

Save and activate.

Open your behavior definition ZCAL_I_HOLIDAY_XXX and disable the physical deletion.
Remove the delete property from the root node.

Add action delete to your behavior definition.

action delete;

Save and activate your behavior definition.
Set the cursor on the action delete definition and press CTRL+1. Click on Add missing method for action delete in new local handler class to create your action method.

Insert following code as your delete method in ZBP_CAL_I_HOLIDAY_XXX:

METHOD delete.
  CONSTANTS no_longer_valid TYPE zconfig_deprecation_code_xxx VALUE 'E'.
  DATA holidayroot_table TYPE TABLE FOR UPDATE zcal_i_holiday_xxx.

  LOOP AT keys ASSIGNING FIELD-SYMBOL(<key>).
    APPEND
      VALUE #( holiday_id            = <key>-holiday_id
               configdeprecationcode = no_longer_valid
               %control              = VALUE #( configdeprecationcode = cl_abap_behv=>flag_changed ) )
         TO holidayroot_table.
  ENDLOOP.

  MODIFY ENTITIES OF zcal_i_holiday_xxx IN LOCAL MODE
    ENTITY HolidayRoot UPDATE FROM holidayroot_table
        MAPPED   DATA(ls_mapped)
        FAILED   DATA(ls_failed)
        REPORTED DATA(ls_reported).
ENDMETHOD.

Save and activate.

Go to ZCAL_I_HOLIDAY_XXX and search for configdeprecationcode and add following UI annotations:

@UI.hidden: true
   @UI.lineItem:
     [ { type: #FOR_ACTION, dataAction: 'delete', label: 'Delete' } ]
   @UI.identification:
     [ { type: #FOR_ACTION, dataAction: 'delete', label: 'Delete' } ]
   configdeprecationcode         as ConfigDeprecationCode,

Check your result.